Датчик тиску температури та вологості BMP280 + AHT20 3,3 В

#include "Wire.h"
#include "Adafruit_BMP280.h"
#include "Adafruit_AHTX0.h"

Adafruit_BMP280 bmp;
Adafruit_Sensor *bmp_temp = bmp.getTemperatureSensor();
Adafruit_Sensor *bmp_pressure = bmp.getPressureSensor();

Adafruit_AHTX0 aht20;

void setup() {
  Serial.begin(115200);
  Serial.println(F("AHT20+BMP280 test"));
  Serial.println();
  delay(2000);

  while (aht20.begin() != true) {
    Serial.println(F("AHT20 not connected or fail to load calibration coefficient"));
    delay(1000);
  }
  Serial.println(F("AHT20 OK"));

  while (bmp.begin() != true) {
    Serial.println(F("Could not find a valid BMP280 sensor, check wiring or "
                     "try a different address!"));
    delay(1000);
  }
  Serial.println(F("BMP280 OK"));
 
  bmp.setSampling(Adafruit_BMP280::MODE_NORMAL,     /* Operating Mode. */
                  Adafruit_BMP280::SAMPLING_X2,     /* Temp. oversampling */
                  Adafruit_BMP280::SAMPLING_X16,    /* Pressure oversampling */
                  Adafruit_BMP280::FILTER_X16,      /* Filtering. */
                  Adafruit_BMP280::STANDBY_MS_500); /* Standby time. */
}

void loop() {

  sensors_event_t humidity, temp;
  aht20.getEvent(&humidity, &temp);

  Serial.println("AHT20");
  Serial.print("Temperature: "); Serial.print(temp.temperature); Serial.println(" degrees C");
  Serial.print("Humidity: "); Serial.print(humidity.relative_humidity); Serial.println("% rH");
  Serial.println();

  sensors_event_t temp_event, pressure_event;
  bmp_temp->getEvent(&temp_event);
  bmp_pressure->getEvent(&pressure_event);

  Serial.println("BMP280");
  Serial.print(F("Temperature = "));
  Serial.print(temp_event.temperature);
  Serial.println(" *C");
  Serial.print(F("Pressure = "));
  Serial.print(pressure_event.pressure);
  Serial.println(" hPa");
  Serial.println();
  delay(2000);
}